100'  NAME--SIGNUP
110'
120'  DESCRIPTION--PRINTS A TELETYPE SIGNUP LIST WITH VARYING TIME
130'  INCREMENTS.
140'
150'  SOURCE--RONALD FAGIN '67.
160'
170'  INSTRUCTIONS--DATA STARTS IN LINE 1000 IN GROUPS OF 3 NUMBERS,
180'  THE FIRST IS THE INITIAL TIME IN THE PERIOD, THE
190'  SECOND IS THE FINAL TIME (IN BOTH CASES ADD 1200 IF TIME IS
200'  AFTER 12:59 A.M.), AND THE THIRD NUMBER IS THE TIME INCREMENT
210'  IN MINUTES. THUS FOR 9:00 TO 12:00 WITH INCREMENTS OF 30
220'  MINUTES FOLLOWED BY 1:00 TO 5:30 WITH INCREMENTS OF 90 
230'  MINUTES THE DATA SHOULD READ:
240'      1000 DATA 900,1200,30,1300,1730,90
250'  TYPE:
260'        380 PRINT"OCTOBER 15"
270'  IF THE WEEK BEGINS ON OCTOBER 15.
280'  GIVE AS PRINT STATEMENTS IN LINES 720-750 ANY MESSAGES YOU
290'  WISH PRINTED OUT SUCH AS A LIMIT ON THE NUMBER OF PERIODS
300'  SOMEONE MAY SIGN UP FOR.
310'
320'
330'  *  *  *  *  *  *  *  MAIN PROGRAM   *  *  *  *  *  *  *  *
340'
350 GOSUB 780
360 GOSUB 780
370 PRINT "TELETYPE SIGNUP LIST FOR THE WEEK BEGINNING ";
380 PRINT "OCTOBER 15"
390 GOSUB 780
400 PRINT TAB(11);"SUNDAY   MONDAY  TUESDAY WEDNESDAY THURSDAY  ";
410 PRINT "FRIDAY SATURDAY"
420 READ A
430 READ B,C
440 LET Q=0
450 IF A>1259 THEN 500
460 IF A>999 THEN 480
470 PRINT " ";
480 PRINT A;
490 GOTO 530
500 IF A>2199 THEN 520
510 PRINT " ";
520 PRINT A-1200;
530 PRINT TAB(9);
540 FOR I=1 TO 6
550 PRINT ":--------";
560 NEXT I
570 PRINT ":-------:"
580 IF A<B THEN 620
590 READ A
600 LET Q=1
610 IF A=-1 THEN 710
620 PRINT TAB(9);
630 FOR I=1 TO 6
640 PRINT ":        ";
650 NEXT I
660 PRINT ":       :"
670 IF Q=1 THEN 430
680 LET K=A-100*INT(A/100)
690 LET A=A+C+40*INT((C+K)/60)
700 GOTO 450
710 GOSUB 780
720 
730 
740 
750 
760 GOSUB 780
770 STOP
780 FOR I=1 TO 5
790 PRINT
800 NEXT I
810 RETURN
1000 DATA 900,1200,30,1300,1730,90
2000 REM  DATA IN LINE 3000 IS PART OF THE PROGRAM.
3000 DATA -1
4000 END