TITLE	PLOTER INSTRUCTION SIMULATION (TYPE 350B)	VERSION #2	SEPT. 1 '69
	SUBTTL	DAVE MCCLURE	JULY /69

	IFN PLOTER,<PASS2
		END>

ENTRY	PLDATA,PLCDAT,PLSF,PLCF,PLPU,PLPR,PLDU,PLPRDU,PLDD,PLPRDD,PLPL,PLUD,PLPLUD,PLPD
EXTERNAL	SWRITE,NTIME,TIME

PLDATA:	4*^D10000/3		;18000 STEPS PER MIN
	Z
	XWD	PLACTI,PLFLG
	Z
PLCDAT:	EXP	A		;ASCII MODE FOR SPOOLING
	SIXBIT	/PLT/
	EXP	PLHEAD,0,PLENTR
	Z
	Z
	Z
	Z
	Z

PLSF:	TRNE	FLAGS,PLFLG	;<6501> SKIP ON PLOTTER FLAG
	AOS	PC
	POPJ	PDP,

PLCF:	TRZ	FLAGS,PLFLG	;<6502> CLEAR THE PLOTTER FLAG
	POPJ	PDP,

PLPU:	MOVEI	AC1,40		;<6504> RAISE THE PEN
	JRST	PLOT

PLPR:	MOVEI	AC1,1		;<6511> PEN RIGHT
	JRST	PLOT

PLDU:	MOVEI	AC1,10		;<6512> DRUM UP
	JRST	PLOT

PLPRDU:	MOVEI	AC1,11		;<6513> DRUM UP AND PEN RIGHT
	JRST	PLOT

PLDD:	MOVEI	AC1,4		;<6514> DRUM DOWN
	JRST	PLOT

PLPRDD:	MOVEI	AC1,5		;<6515> DRUM DOWN AND PEN RIGHT
	JRST	PLOT

PLPL:	MOVEI	AC1,2		;<6521> PEN LEFT
	JRST	PLOT

PLUD:	MOVEI	AC1,10		;<6522> DRUM UP
	JRST	PLOT

PLPLUD:	MOVEI	AC1,12		;<6523> DRUM UP AND PEN LEFT
	JRST	PLOT

PLPD:	MOVEI	AC1,20		;<6524> PEN LOWER
	JRST	PLOT

PLOT:	TLO	FLAGS,PLACTIVE	;SET PLOTTER ACTIVE
	SOSG	PLHEAD+2	;BUFFER FULL?
	JRST	PLOT1		;YES
	IDPB	AC1,PLHEAD+1	;WRITE ONE CHARACTER
	MOVE	AC1,TIME	;LOAD CURRENT SIMULATED TIME
	ADD	AC1,PLDATA	;ADD DELAY FOR FLAG
	CAMGE	AC1,NTIME	;NEXT FLAG?
	MOVEM	AC1,NTIME	;YES
	POPJ	PDP,

PLOT1:	MOVEI	FDB,PLCDAT
	PUSHJ	PDP,SWRITE
	JRST	PLOT+3

PLENTR:	SIXBIT	/PLOTS/
	SIXBIT	/OUT/
	Z
	Z
PLHEAD:	BLOCK	3

	END