100'  NAME--APAWAM
110'
120'  DESCRIPTION--PLAYS A ROUND OF GOLF AT THE APAWAMIS COUNTRY CLUB.
130'
140'  SOURCE--UNKNOWN
150'
160'  INSTRUCTIONS--TYPE "RUN" AND FOLLOW INSTRUCTIONS.
170'
180'
190'  *  *  *  *  *  *  *   MAIN PROGRAM   *  *  *  *  *  *  *  *  *
200'
210 REM  *  APAWAM  *
220 RANDOMIZE
230 MAT READ A$(9)
240 DATA FIRST,SECOND,THIRD,FOURTH,FIFTH,SIXTH,SEVENTH
250 DATA EIGHTH,NINTH AND FINAL
260PRINT"YOU ARE ABOUT TO PLAY A ROUND OF GOLF AT THE APAWAMIS COUNTRYCLUB,"
270PRINT
280PRINT"   THESE ARE YOUR CLUBS:"
290PRINT"                        1 - 4  WOODS"
300PRINT"                        2 - 9  IRONS"
310PRINT"                        1 - 10 PUTTER"
320PRINT"                         11    WEDGE"
330PRINT"(TO HONOR THE GREAT BOBBY JONES, ADD 10 TO YOUR IRON SELECTION."
340PRINT"(FOR EXAMPLE: TO USE A 3 IRON, TYPE 13. FOR A 4 IRON, TYPE 14."
350PRINT
360PRINT"A PUTTER CAN BE USED ONLY ON THE GREEN. IF YOU INPUT 10 AS A"
370PRINT"PUTT, THE BALL WILL BE HIT ABOUT 50 FEET. A 1 WILL TAP THE BALL."
380PRINT
390 IF S+1=10 THEN 1620
400 PRINT
410 PRINT
420 READ B
430 READ D
440 PRINT "YOU ARE AT THE "A$(S+1);" TEE OF THE APAWAMIS GOLF COURSE."
450PRINT"IT IS"B"YARDS LONG,  PAR"D"."
460 LET S=S+1
470 LET C=0
480PRINT
490 IF INT(B)=0 THEN 1550
500PRINT"WHICH CLUB DO YOU CHOOSE";
510 LET C=C+1
520INPUT A
530IF A>0 THEN 590
540 IF A=11 THEN 1210
550IF A>11 THEN 1310
560PRINT"INPUT DATA NOT IN CORRECT FORMAT. RETYPE IT."
570GOTO 520
580   REM
590 IF A>4 THEN 540
600 LET X=INT(RND*250)
610 IF X<220 THEN 600
620 LET Y=INT(RND*30)
630 IF X/11=INT(X/11) THEN 740
640 IF X/5=INT(X/5)THEN 870
650 IF X/28=INT(X/28) THEN 780
660 IF X/27=INT(X/27) THEN 920
670 IF X-(A*Y)+20<B THEN 710
680 IF X-(A*Y)-25>B THEN 810
690 LET B=INT(1.7*Y)
700 GOTO 1820
710PRINT"YOU HIT IT"X-(A*Y)"YARDS. YOU ARE"B-(X-(A*Y))"YARDS FROM THE GREEN."
720 LET B=B-(X-(A*Y))
730 GOTO 480
740IF X-(A*Y)>B THEN 820
750PRINT"YOU ARE IN THE LEFT ROUGH,"B-(X-(A*Y))"YARDS FROM THE GREEN."
760 LET B=B-(X-(A*Y))
770 GOTO 480
780PRINT"YOU SLICED THE BALL INTO A POND. LOSE TWO STROKES AND REPLAY."
790 LET C=C+1
800 GOTO 480
810 IF Y/A=9 THEN 850
820PRINT"YOU ARE IN A TRAP NEAR THE GREEN."
830 LET B=20
840 GOTO 480
850PRINT" YOU HAVE S*U*N*K THE SHOT............(BIG DEAL)"
860 GOTO 1590
870 IF Y/6=A THEN 920
880 IF B-20<X-(A*Y) THEN 670
890PRINT"YOU ARE IN THE RIGHT ROUGH,"B-(X-(A*Y))+25"YARDS FROM THE GREEN."
900 LET B=B-(X-(A*N))
910 GOTO 480
920 PRINT"THE BALL IS LOST IN THE WOODS. REPLAY AND LOSE TWO STROKES."
930 LET C=C+1
940 GOTO 480
950   REM
960 LET Q=INT(RND*10)
970 IF Q/15=INT(Q/15) THEN 1100
980 IF B>10 THEN 1060
990 IF B>5 THEN 1150
1000 IF Q=7 THEN 1030
1010PRINT"THE TAP IS GOOD."
1020 GOTO 1550
1030PRINT"WHAT? YOU MISSED THE TAP. YOU ARE"B"INCHES FROM THE HOLE."
1040 LET B=1
1050 GOTO 1670
1060 IF Q/3=INT(Q/3) THEN 1170
1070 PRINT"YOU ARE NOW"INT((B/10))"FEET FROM THE PIN"
1080 LET B=B/10
1090 GOTO 1670
1100PRINT"YOU  S*U*N*K  IT FROM"B"FEET."
1110 GOTO 1550
1120 IF INT((B*9)/10)<=1 THEN 1100
1130 LET B=INT(B/10)
1140 GOTO 1670
1150 IF Q=4 THEN 1100
1160 IF Q/2=INT(Q/2) THEN 1100
1170 PRINT"YOU ARE NOW"INT((B*3)/10)"FEET FROM THE PIN."
1180 LET B=INT((B*3)/10)
1190 GOTO 1670
1200  REM
1210 IF B>75 THEN 560
1220 IF B/28=INT(B/28) THEN 1490
1230 IF B<40 THEN 1270
1240 IF B/20=INT(B/20) THEN 1490
1250 LET B=INT(.6*B)
1260 GOTO 1820
1270 LET L=RND
1280 LET B=B*L
1290 GOTO 1820
1300  REM
1310 LET M=INT(RND*235)
1320 IF A>19 THEN 560
1330 IF M<200 THEN 1310
1340 LET N=INT(RND*5)
1350 IF N<3 THEN 1340
1360 IF B-(M-(A*N))<15 THEN 1510
1370 IF B-(M-(A*N))<25 THEN 1460
1380 IF M/27=INT(M/27) THEN 920
1390 REM
1400 IF M/8=INT(M/8) THEN 820
1410 IF M/69=INT(M/69) THEN 1490
1420PRINT"YOUR SHOT WENT "INT(M-(A*N))"YARDS. YOU ARE NOW"
1430PRINT B-(INT(M-(A*N)))"YARDS FROM THE GREEN."
1440 LET B=INT(ABS(B-(M-(A*N))))
1450 GOTO 480
1460 IF B-25>M-(A*N) THEN 820
1470 LET B=5*N
1480 GOTO 1820
1490PRINT"YOU  S*U*N*K  IT."
1500 GOTO 1590
1510 IF B-15>M-(A*N) THEN 1370
1520 LET B=INT(ABS(B-(M-(A*N))))
1530 GOTO 1820
1540  REM
1550PRINT
1560 LET E=E+C
1570PRINT"YOU HAVE HAD "C"STROKES ON HOLE NO. "S"."
1580 GOTO 380
1590 IF C<>1 THEN 1550
1600PRINT" **HOLE IN ONE**"
1610 GOTO 1550
1620 PRINT"AFTER 9 HOLES YOU HAVE HAD"E"STROKES."
1630 PRINT"THE PAR IS 36.  YOU ARE"E-36"OVER PAR."
1640 STOP
1650 DATA 374,4,434,4,210,3,376,4,205,3,440,4,422,4,510,5,595,5
1660DATA 510,5,434,4,210,3,312,4,428,4,440,4,205,3,515,5,318,4
1670 PRINT
1680 IF INT(B)=0 THEN 1590
1690 LET C=C+1
1700PRINT"WHAT IS YOUR PUTT";
1710 INPUT A
1720 LET T=RND*5.5
1730IFT<4.5THEN1720
1740 IF A>10 THEN 1770
1750 IF A<1 THEN 1770
1760 GOTO 1790
1770PRINT"CAN'T USE THAT. RETYPE."
1780 GOTO 1710
1790 IF A*T+8<B THEN 1170
1800 IF A*T-8>B THEN 1170
1810 GOTO 960
1820 PRINT"YOU ARE ON THE GREEN,"B"FEET FROM THE PIN."
1830 GOTO 1670
1840 END