.TITLE	PCR -- PAPER TAPE READ PROGRAM
	.IDENT	/V01.00/

PRS	==	177550

$USRSP	==	42
$ERRBY	==	52
$USRRB	==	53

FATAL$	==	10

CHAN0	=	0
EOL	=	200

	.MCALL	.CLOSE,.CSIGEN,.EXIT,.GTLIN,.PRINT
	.MCALL	.PURGE,.WRITW

PCREP::	MOV	#LINBUF,R1
	.GTLIN	R1,#PROMPT
	TSTB	@R1
	BNE	10$
	.PRINT	#IDENT
	BR	PCREP

10$:	MOV	R1,R2
20$:	CMPB	#'=,@R2
	BEQ	40$
	CMPB	#',,(R2)+
	BEQ	40$
	TSTB	@R2
	BNE	20$
	MOVB	#'=,(R2)+
	CLRB	@R2
	.CSIGEN	#DEVSPC,#DEFEXT,R1
	BCC	50$
	CLR	R0
	BISB	@#$ERRBY,R0
	CMPB	#4,R0
	BGT	30$
	MOV	#4,R0
30$:	ASL	R0
	.PRINT	ERRTB(R0)
	.PURGE	#CHAN0
	BISB	#FATAL$,@#$USRRB
	BR	PCREP
40$:	CLR	R0
	BR	30$

50$:	TST	(SP)+
	BEQ	60$
	MOV	@#$USRSP,SP
	BR	40$

60$:	CLR	R4
	MOV	CSR,R5
70$:	MOV	#BUFF,R1
	MOV	#256.*2,R2
80$:	INC	@R5
	TSTB	@R5
	BPL	.-2
	TST	@R5
	BMI	100$
	MOVB	2(R5),(R1)+
	SOB	R2,80$

	.WRITW	#AREA,#CHAN0,#BUFF,#256.,R4
	BCS	90$
	INC	R4
	BR	70$

90$:	MOV	#5,R0
	BR	30$

100$:	CMP	#512.,R2
	BEQ	120$
110$:	CLRB	(R1)+
	SOB	R2,110$
	.WRITW	#AREA,#CHAN0,#BUFF,#256.,R4
	BCS	90$
	INC	R4
120$:	TST	R4
	BNE	130$
	MOV	#6,R0
	BR	30$

130$:	.CLOSE	#CHAN0
	JMP	PCREP

CSR:	.WORD	PRS
DEFEXT:	.RAD50	/LDALDALDALDA/
BUFF:	.BLKW	256.
AREA:	.BLKW	5

LINBUF:	.BLKB	82.
PROMPT:	.ASCII	/*/<EOL>
IDENT:	.ASCIZ	/PCR V01.00/

ERR0:	.ASCIZ	/?PCR-F-Invalid command/
ERR1:	.ASCIZ	/?PCR-F-Illegal device/
ERR2:	.ASCIZ	/?PCR-F-Protected file already exists/
ERR3:	.ASCIZ	/?PCR-F-Output device full/
ERR4:	.ASCIZ	/?PCR-F-Unknown CSI error/
ERR5:	.ASCIZ	/?PCR-F-Output error/
ERR6:	.ASCIZ	/?PCR-F-No data/
	.EVEN

ERRTB:	.WORD	ERR0,ERR1,ERR2,ERR3,ERR4,ERR5,ERR6

DEVSPC:

	.END	PCREP