.TITLE	EBC -- ADD 8BIT SUPPORT
	.IDENT	/V01.00/

$JSX	=	4			;EXTENDED JOB STATUS WORD
NOVBG$	=	100			;DISABLE VBGEXE BIT
$SYPTR	=	54			;RMON POINTER
$SYSGE	=	372			;SYSGEN CONFIG WORD
MTTY$	=	20000			;MULTI-TERMINAL SYSTEM BIT

	.MCALL	.EXIT,.PRINT		;SYSTEM MACRO CALLS

	.ASECT
	.=$JSX
	.WORD	NOVBG$
	.PSECT

INFO::	.WORD	0			;INFORM ONLY FLAG

EBCEP::	MOV	@#$SYPTR,R5		;GET RMON BASE ADDRESS
	BIT	#MTTY$,$SYSGE(R5)	;MULTI-TERMINAL SYSTEM?
	BEQ	10$			;EQ -> NO
	.EXIT

10$:	CMP	#142714,@R5		;LOCATE BIC(B) #PTYMSK/#FIXCHR
	BEQ	25$
	CMP	#142704,@R5
	BEQ	30$
	CMP	#042704,#R5
	BEQ	30$
	TST	(R5)+
20$:	CMP	#160000,R5		;END OF SYSTEM?
	BNE	10$			;NE -> NO
	.EXIT

25$:	MOV	R5,R1			;
	TST	(R5)+			;SKIP OVER INSTRUCTION
	CMP	#200,@R5
	BNE	10$
	TST	INFO
	BNE	40$
	BR	35$

30$:	MOV	R5,R1			;COPY INSTRUCTION ADDRESS
	TST	(R5)+			;SKIP OVER INSTRUCTION
	CMP	#177600,@R5		;FIXCHR/PTYMSK?
	BNE	10$			;NO
	TST	INFO			;INFORM ONLY?
	BNE	40$			;YES
35$:	BIC	#200,(R5)+		;UPDATE MASK
	BR	20$			;LOOP

40$:	TST	(R5)+			;SKIP MASK
	MOV	#BUFF,R0		;SET BUFFER ADDRESS
	MOV	PC,R2			;DON'T STRIP LEADING ZEROES
	CALL	$CBOMG			;CONVERT ADDRESS TO ASCII
	.PRINT	#BUFF			;PRINT ADDRESS
	BR	20$			;LOOP

BUFF:	.ASCIZ	/XXXXXX/		;BUFFER

	.END	EBCEP