.TITLE	PDRW -- TEST PDR W-BIT BEHAVIOR
	.IDENT	/V01.00/

PSW	=	177776			;PROCESSIR STATUS WORD

KISAR0	=	172340			;KERNEL I-SPACE ADDRESS REGISTER 0
KISDR0	=	172300			;KERNEL I-SPACE DESCRIPTOR REGISTER 0
KISAR7	=	172356			;KERNEL I-SPACE ADDRESS REGISTER 7
KISDR7	=	172316			;KERNEL I-SPACE DESCRIPTOR REGISTER 7

MMR0	=	177572			;MEMORY MANAGEMENT REGISTER 1
MMR3	=	172516			;MEMORY MANAGEMENT REGISTER 3

PR7	=	340			;PRIORITY 7

	.MCALL	.EXIT,.PRINT		;SYSTEM MACROS

START::	MOV	#SAVE,R5		;BUFFER RO SAVE CONTEXT
	MOV	@#PSW,(R5)+		;SAVE PSW
	MOV	@#MMR0,(R5)+		;SAVE MMR0
	MOV	@#MMR3,(R5)+		;SAVE MMR3
	MOV	@#KISAR0,(R5)+		;SAVE KISAR0
	MOV	@#KISDR0,(R5)+		;SAVE KISDR0
	MOV	@#KISAR7,(R5)+		;SAVE KISAR7
	MOV	@#KISDR7,(R5)+		;SAVE KISDR7
	MOV	#PDRS,R0		;BUFFER TO SAVE PDR VALUES
	MOV	#PR7,@#PSW		;PRIORITY 7, KERNEL MODE

	CLR	@#MMR0			;;;DISABLE RELOCATION
	MOV	#20,@#MMR3		;;;22-BIT, NO I&D
	MOV	#77406,@#KISDR0		;;;INITIALIZE KISDR0
	MOV	#77406,@#KISDR7		;;;INITIALIZE KISDR7
	CLR	@#KISAR0		;;;INITIALIZE KISAR0
	MOV	#177600,@#KISAR7	;;;INITIALIZE KISAR7
	MOV	#1,@#MMR0		;;;ENABLE RELOCATION

	MOVB	@#KISDR7+1,@#KISDR7+1	;;;
	MOV	@#KISDR7,(R0)+		;;;

	MOV	@#PSW,@#PSW		;;;
	MOV	@#KISDR7,(R0)+		;;;

	MOVB	@#KISDR7+1,@#KISDR7+1	;;;
	MOV	@#KISDR7,(R0)+		;;;

	MOV	@#PSW,@#PSW		;;;
	MOV	@#KISDR7,(R0)+		;;;

	MOV	@#KISAR7,@#KISAR7	;;;
	MOV	@#KISDR7,(R0)+		;;;

	BIS	#100,@#KISDR7		;;;
	MOV	@#KISDR7,(R0)+		;;;

	BIC	#100,@#KISDR7		;;;
	MOV	@#KISDR7,(R0)+		;;;

	CLR	@#MMR0			;;;DISABLE RELOCATION
	MOV	-(R5),@#KISDR7		;;;RESTORE KISDR7
	MOV	-(R5),@#KISAR7		;;;RESTORE KISDR7
	MOV	-(R5),@#KISDR0		;;;RESTORE KISDR0
	MOV	-(R5),@#KISAR0		;;;RESTORE KISAR0
	MOV	-(R5),@#MMR3		;;;RESTORE MMR3
	MOV	-(R5),@#MMR0		;;;RESTORE MMR0
	MOV	-(R5),@#PSW		;;;RESTORE PSW

	MOV	#BUFF,R0		;OUTPUT BUFFER
	MOV	#FMTS,R1		;FORMAT STRING
	MOV	#PDRS,R2		;ARGUMENT BLOCK
	CALL	$EDMSG			;EDIT MESSAGE
	.PRINT	#BUFF			;PRINT IT
	.EXIT				;EXIT

SAVE:	.BLKW	7			;CONTEXT SAVE BUFFER
PDRS:	.BLKW	7			;BUFFER TO SAVE PDRS
BUFF:	.BLKB	256.			;OUTPUT BUFFER

FMTS:	.ASCII	/MOVB	@#KISDR7,@#KISDR7	;KISDR7=%P%N/
	.ASCII	/MOV	@#PSW,@#PSW		;KISDR7=%P%N/
	.ASCII	/MOVB	@#KISDR7,@#KISDR7	;KISDR7=%P%N/
	.ASCII	/MOV	@#PSW,@#PSW		;KISDR7=%P%N/
	.ASCII	/MOV	@#KISAR7,@#KISAR7	;KISDR7=%P%N/
	.ASCII	/BIS	#100,@#KISDR7		;KISDR7=%P%N/
	.ASCIZ	/BIC	#100,@#KISDR7		;KISDR7=%P/

	.END	START