                             >>40<< seq break
3/	jmp 20
20/
	cks
	ril 1
	spi
red,	jmp .
	ril 1
	spi
typ,	jmp .
	ril 3
	spi
pun,	jmp .
	hlt		/unkown break
deb,	lac 0
	lio 2
	jmp i 1		/debreak
	cbs=720056

	u=-opr


aaa,	load red,nop
	load typ,jmp a
	lio (34
	tyo
	jmp a-2
3777/	hlt u clf 7		/initial halt
	jmp . 2
a,	hlt		/start clear allowed break
	lio (777777
	cks
	swap
	add (777777
	sza i
	hlt		/cks 7-4,10-4 missing
	ral 77
	sma
	hlt		/seq status,not sbm
	lsm
	cbs
	rrb
	tyi
	load red,nop
	load typ,nop
	load pun,nop
	load pun 1,hlt
	cks
	ril 77
	spi
e2,	hlt		/seq status is set
	cbs
	esm		/enter mode ,clear system
	cks
	qil 77
	spi i
e3,	hlt		/seq status not set
	law i 1
	add (400000
	szo i
e4,	hlt		/ov did not work
	szo
e5,	hlt		/ov did not clear

	load 1,e7-1 400000
	jmp i 1	/test sbs restore
	szo i		/sbs restore failed
e7,	hlt		/to set ov flop

	law i 1
	add (400000
	load 1,c
	jmp i 1
c,	szo		/debreak failed to
e8,	hlt		/clear ov flop

	load 0,d 400000
	jmp i 0
d,	szo
e9,	hlt		/mbd a faileu
	load 11,e 400000
	jmp i 11
e,	szo
e10,	hlt		/MBD b
	load 101,f 400000
	jmp i 101
f,	szo
e11,	hlt		/MBD c
	load 1001, g 400000
	jmp i 1001









g,	szo
e12,	hlt		/MBD d
	lsm
	load 1,k 400000
	jmp i 1
k,	szo
	hlt		/restore pulse,sbm=0
	esm
	load 1,jmp k 6
	jmp 1
	szo
	hlt		/jmp 1,restore pulse

	lsm		/leave seq mode
	load typ,jmp e13
	lio (34
	tyo
	repeat 2,nop
	jmp . 2
e13,	hlt		/tyo caused break

	load typ,jmp e14 1
	esm		/enter seq mode
	repeat 2,nop
e14,	hlt		/b3 or b4 cleared
	load typ,jmp e15
	lio (34
	tyo
	repeat 2,nop
	jmp . 2
e15,	hlt		/break without debreak
	load typ,jmp e16
	cbs
	repeat 2,nop
	jmp . 2
e16,	hlt		/b2 set,check cbs
	load typ,jmp e17 1
	lio (34
	tyo
	repeat 2,nop
e17,	hlt		/fail to break,check cbs
	load typ,jmp e18
	load 1,e18 1
	jmp i 1
	repeat 2,nop
e18,	hlt		/b2fail to clear,bc1

	load typ,jmp e19 1
	lio (34
	tyo		/checking 1l3 u-v-w
	repeat 2,nop
e19,	hlt		/fail to break

	cbs
	dzm 0
	dzm 2
	load typ,jmp e20 1
	law i 1
	add (400000
	lac (252525
	lio (34
	tyo
	lio (525252
e20,	hlt		/tyo fail to break
	lac 0
	sza i
e21,	hlt		/ac not stored
	sas (252525
e22,	hlt		/ac stored incorrect
	lac 2
	sza i
e23,	hlt		/io not stored
	sad (525252
e24,	hlt		/2 cycle inst compleated
	sas (34
e25,	hlt		/io stored incorrectly
	lac 1
	sma
e26,	hlt		/ov not stored
	szo
	hlt		/ov not cleared,bc1
	sad (e20-2 400000
	jmp pok
	sad (e20-1 400000
	jmp pok
	sad (e20 400000
	hlt		/-1 pc,sbs break
	hlt		/pc stored incorrect
pok,	load 1,e27-1 400000
	jmp i 1
	szo i
e27,	hlt		/ov not restored
	cla
	load typ,jmp e32 1
	lio (34
	tyo
m,	jsp i . 1
	.+1 i
	.+1		/test jsp i
e32,	hlt		/fail to break
	lac 0
	sza
	hlt		/ac altered by jsp i
	lac 1
	sad (m-1
	jmp ok
	sas (m
	hlt		/pc storage or -1 pc
ok,	cbs
	load typ,jmp e37-1
	lio (34
	cla u cma
	tyo
	lac i . 2
e36,	hlt		/no break
	.+1
	252525

	lac 0
	sad (252525
e37,	hlt		/break permit,defer
	lac 1
	sad (e36-2
	jmp e39 1
	sad (e36-1
	jmp e39 1
	sad (e36
e38,	hlt		/-1 pc,defer
e39,	hlt		/pc stored incorrect
	cbs
	szs i 10
	jmp a 1
	szf 2
	jmp e40 3
	load typ,nop
	load pun,jmp e40 1
	cli u stf 2
	ppa
	repeat 2,nop
e40,	hlt		/punch fails to break
	load pun,nop
	cbs
	load pun 1,jmp e41
	load typ,jmp e42
	load red,jmp e42 4
	720001
	lio (34
	tyo
	repeat 2,nop
	cks
	ril 3
	spi i
e41,	hlt		/ioh not restored
	cbs
	jmp a 1
e42,	hlt		/no reader break
	load pun 1,hlt
	jmp .-5
	rrb		/clear status,iot inst
	load typ,jmp e41-3
	jmp i 1		/debreak reader
constants
variables
	start aaa
                                              >>13<<                                                                                                                r7
>>14<<4>>34<<                                                                                                                                                       
